如何使用另一个 XML 文件中的属性值作为当前 XML 中的元素值选择 [英] How to use attribute values from another XML file as an element value selection in the current XML
本文介绍了如何使用另一个 XML 文件中的属性值作为当前 XML 中的元素值选择的处理方法,对大家解决问题具有一定的参考价值,需要的朋友们下面随着小编来一起学习吧!
问题描述
我有两个 XML 文件.一个是主要的 XML 文件,另一个用作查找表.这是主要的 XML:
I have two XML files. One is the main XML file and the other one is used as a lookup table. Here is the main XML:
<Report>
<row>
<field1>test1</field1>
<field2>test2</field2>
<field3>test3</field3>
</row>
<row>
<field1>test4</field1>
<field2>test5</field2>
<field3>test6</field3>
</row>
</Report>
查找 xml 文件如下所示:
The lookup xml file looks like this:
<lookup>
<fieldmapping name="field1">fieldA</fieldmapping>
<fieldmapping name="field2">fieldB</fieldmapping>
<fieldmapping name="field3">fieldC</fieldmapping>
</lookup>
这是我想要的输出xml:
Here is the output xml I want:
<Items>
<Item>
<FieldName name="fieldA">test1</FieldName>
<FieldName name="fieldB">test2</FieldName>
<FieldName name="fieldC">test3</FieldName>
</Item>
<Item>
<FieldName name="fieldA">test4</FieldName>
<FieldName name="fieldB">test5</FieldName>
<FieldName name="fieldC">test6</FieldName>
</Item>
</Items>
我正在使用以下 XSLT,但不知道如何从 field1、field2 和 field3 中选择值:
I am using the following XSLT and can not figure out how to select the value from field1, field2, and field3:
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:variable name="mappingLookupDoc" select="document('lookup.xml')/lookup/fieldmapping "/>
<xsl:key name="mappingKey" match="fieldmapping " use="@name"/>
<xsl:template match="report">
<xsl:apply-templates select="$mappingLookupDoc"/>
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="/">
<Items xmlns="http://www.w3.org/1999/xhtml" schemaVersion="1.0">
<xsl:for-each select="report/row">
<Item>
<xsl:for-each select="$mappingLookupDoc">
<xsl:variable name="fieldname" select="@name"/>
<FieldName>
<xsl:attribute name="name">
<xsl:value-of select="." />
</xsl:attribute>
<xsl:value-of select="/report/row/?????"/>
</FieldName>
</xsl:for-each>
</Item>
</xsl:for-each>
</Items>
</xsl:template>
推荐答案
我会这样做(假设 XSLT 2.0):
I would do it like this (assuming XSLT 2.0):
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="2.0">
<xsl:strip-space elements="*"/>
<xsl:output indent="yes"/>
<xsl:key name="k1" match="fieldmapping" use="@name"/>
<xsl:variable name="lookupDoc" select="doc('lookup.xml')"/>
<xsl:template match="Report">
<Items>
<xsl:apply-templates/>
</Items>
</xsl:template>
<xsl:template match="row">
<Item>
<xsl:apply-templates/>
</Item>
</xsl:template>
<xsl:template match="row/*">
<fieldName name="{key('k1', local-name(), $lookupDoc)}">
<xsl:value-of select="."/>
</fieldName>
</xsl:template>
</xsl:stylesheet>
这是对上述 XSLT 2.0 样式表的 XSLT 1.0 重写:
[edit] Here is an XSLT 1.0 rewrite of the above XSLT 2.0 stylesheet:
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<xsl:strip-space elements="*"/>
<xsl:output indent="yes"/>
<xsl:key name="k1" match="fieldmapping" use="@name"/>
<xsl:variable name="lookupDoc" select="document('lookup.xml')"/>
<xsl:template match="Report">
<Items>
<xsl:apply-templates/>
</Items>
</xsl:template>
<xsl:template match="row">
<Item>
<xsl:apply-templates/>
</Item>
</xsl:template>
<xsl:template match="row/*">
<xsl:variable name="this" select="."/>
<xsl:variable name="lookup">
<xsl:for-each select="$lookupDoc">
<xsl:value-of select="key('k1', local-name($this))"/>
</xsl:for-each>
</xsl:variable>
<fieldName name="{$lookup}">
<xsl:value-of select="."/>
</fieldName>
</xsl:template>
</xsl:stylesheet>
这篇关于如何使用另一个 XML 文件中的属性值作为当前 XML 中的元素值选择的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!
查看全文