如何使用 Applescript 检查 Chrome 是否在隐身模式下运行? [英] How to check is Chrome is running in incognito mode using Applescript?

问题描述

是否可以确定 Chrome 是否在隐身模式下运行?

Is it possible to find out if the Chrome is running in incognito mode?

if application "Google Chrome" is running then
    tell application "Finder" to display dialog "Chrome is running"
    // --> some condition here to check if it is in incognito ?
       tell application "Finder" to display dialog "Chrome is running in INCOGNITO mode"
end if

另外，我希望这个脚本继续运行.这意味着只要用户以隐身模式打开 Chrome，我就会显示警报.像这样:

Also, I want this script to keep running. That means as soon as user opens Chrome in incognito mode I will show alert. Like this:

set chromeRunning to false
repeat until application "Google Chrome" is running

    if not chromeRunning then
        tell application "Finder" to display dialog "Chrome is started in INCOGNITO mode"
        set chromeRunning to true
        #may be quit the script now..
    end if
    delay 10
end repeat

如果这是正确的方法?

推荐答案

我不知道你为什么要把 Q 移到另一个论坛.这是一个关于使用 Applescript 的好问题.模式是每个窗口的属性！一个使用它关闭所有浏览器窗口的小例子:

I don't know why you want to move the Q to another forum. It is a nice question about using Applescript. The mode is a property of each window! A little example to close all browser windows using it:

tell application "Google Chrome"
    close (every window whose mode is "incognito")
end tell

要保持脚本运行，您必须将其保存为应用程序，并选中运行处理程序后保持打开状态.在脚本中，您需要定义 on idle-handler:

To keep a script running you have to save it as an Application with Stay open after run handler checked. Inside the script you need to define the on idle-handler:

on idle
    -- do your stuff
    -- repeat after 10 seconds
    return 10
end idle

综合起来，我们得到如下结果:

Putting all together we get something like:

on idle
    if application "Google Chrome" is running then
        tell application "Google Chrome"
            set incognitoWindows to (every window whose mode is "incognito")
        end tell

        if (count of incognitoWindows) > 0 then
            activate
            display dialog "Chrome is running in incognito mode!"
        end if
    end if

    -- repeat after 10 seconds
    return 10
end idle

玩得开心，迈克尔/汉堡

Have fun, Michael / Hamburg

这篇关于如何使用 Applescript 检查 Chrome 是否在隐身模式下运行?的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！