如何通过通常的 System.IO 类访问网络驱动器? [英] How do I access a network drive through the usual System.IO classes?

问题描述

我的软件处理多个文件操作，现在我已经完成了相关函数的编写，使用System.IO类.

My software handles multiple operations on files, and I have now finished writing the related functions, using the System.IO classes.

我现在需要添加对网络驱动器的支持.使用映射效果很好(虽然Directory.GetFiles有点低，我也不知道为什么)，但我现在希望能够直接处理\192.168.0.10共享文件夹MyDrive.除了将驱动器安装到可用的驱动器号，使用新生成的路径，然后卸载之外，还有什么方法可以处理这种类型的路径?

I now need to add support for network drives. Using a mapping works very well (although Directory.GetFiles is a bit low, and I don't know why), but I'd now like to be able to deal directly with paths such as \192.168.0.10Shared FolderMyDrive. Is there any way to handle this type of paths other than mounting the drive to an available drive letter, using the newly generated path, and then unmounting?

推荐答案

您可以直接在路径中使用 UNC 路径(以 \ 开头).但是，您必须考虑此连接的凭据，这可能是棘手的部分.

You can use the UNC path (which starts with \) directly in your paths. However, you must account for the credentials for this connection, which can be the tricky part.

有几种方法:

1. 如果远程系统在同一个域中或者域之间存在信任关系，并且您的程序运行的用户具有合适的访问权限，它就会正常工作".

1. If the remote system is on the same domain or there is a trust relationship between the domains, and the user your program is running as has suitable access, it will "just work".

您可以退出并执行 net use 命令(通过 Windows net.exe 程序)以使用特定的用户名和密码建立连接.请注意，在用户会话中运行的任何程序都可以使用连接，而不仅仅是您的应用程序.完成后使用 /DELETE 命令删除连接.典型的语法是:net use \computernamesharename password/USER:domainusername.

You can shell out and execute the net use command (through the Windows net.exe program) to make a connection with a specific username and password. Be aware that connection is usable by any program running in the user's session, not just your application. Use the /DELETE command to remove the connection when you are done. The typical syntax is: net use \computernamesharename password /USER:domainusername.

您可以 P/Invoke WNetAddConnection2 来完成与 net use 相同的事情，而无需使用 net.exe.通过将 NULL 作为 lpLocalName 传递，不会分配驱动器号，但用户名和密码将应用于通过 UNC 路径进行的后续访问.WNetCancelConnection2 函数可用于断开连接.

You can P/Invoke WNetAddConnection2 to accomplish the same thing as net use without shelling out to net.exe. By passing NULL as lpLocalName, no drive letter is assigned, but the username and password will apply to subsequent accesses made through the UNC path. The WNetCancelConnection2 function can be used to disconnect.

您可以使用 LOGON32_LOGON_NEW_CREDENTIALS 标志 P/Invoke LogonUser，然后模拟以向您的线程添加其他远程凭据.与#2 和#3 不同，对用户整个会话的影响会更有限.(实际上，这很少有利于著名的 WNetAddConnection2 解决方案.)

You can P/Invoke LogonUser with the LOGON32_LOGON_NEW_CREDENTIALS flag followed by an impersonation to add additional remote credentials to your thread. Unlike #2 and #3, the effects on the user's entire session will be a little more limited. (In practice, this is rarely done in favor of the well-known WNetAddConnection2 solution.)

以下是如何从 VB.NET 调用 WNetAddConnection2 的示例.

The following is a sample of how to call WNetAddConnection2 from VB.NET.

Private Sub Test()
    Dim nr As New NETRESOURCE
    nr.dwType = RESOURCETYPE_DISK
    nr.lpRemoteName = "\computershare"
    If WNetAddConnection2(nr, "password", "user", 0) <> NO_ERROR Then
        Throw New Exception("WNetAddConnection2 failed.")
    End If
    'Code to use connection here.'
    If WNetCancelConnection2("\computershare", 0, True) <> NO_ERROR Then
        Throw New Exception("WNetCancelConnection2 failed.")
    End If
End Sub

<StructLayout(LayoutKind.Sequential)> _
Private Structure NETRESOURCE
    Public dwScope As UInteger
    Public dwType As UInteger
    Public dwDisplayType As UInteger
    Public dwUsage As UInteger
    <MarshalAs(UnmanagedType.LPTStr)> _
    Public lpLocalName As String
    <MarshalAs(UnmanagedType.LPTStr)> _
    Public lpRemoteName As String
    <MarshalAs(UnmanagedType.LPTStr)> _
    Public lpComment As String
    <MarshalAs(UnmanagedType.LPTStr)> _
    Public lpProvider As String
End Structure

Private Const NO_ERROR As UInteger = 0
Private Const RESOURCETYPE_DISK As UInteger = 1

<DllImport("mpr.dll", CharSet:=CharSet.Auto)> _
Private Shared Function WNetAddConnection2(ByRef lpNetResource As NETRESOURCE, <[In](), MarshalAs(UnmanagedType.LPTStr)> ByVal lpPassword As String, <[In](), MarshalAs(UnmanagedType.LPTStr)> ByVal lpUserName As String, ByVal dwFlags As UInteger) As UInteger
End Function

<DllImport("mpr.dll", CharSet:=CharSet.Auto)> _
Private Shared Function WNetCancelConnection2(<[In](), MarshalAs(UnmanagedType.LPTStr)> ByVal lpName As String, ByVal dwFlags As UInteger, <MarshalAs(UnmanagedType.Bool)> ByVal fForce As Boolean) As UInteger
End Function

这篇关于如何通过通常的 System.IO 类访问网络驱动器?的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！