将数据从excel工作表分解成多个工作簿 [英] Splitting data from excel worksheet into multiple workbooks

问题描述

我正在将数据分成多个工作簿，这些工作簿将带有我的独特价值的名称。
每月需要执行几次，所以我正在寻找一个自动化解决方案。

I'm looking to split my data into multiple workbooks that will carry the name of my "unique value". Need to perform this several times per month, so am looking for an automated solution.

我有大约20列，列A包含唯一的值，其中可以重复几次。其他列携带有关唯一值的信息。
如果文件的原始格式保留，我也会更喜欢。

I have about 20 columns, column A contains the unique value, which can be repeated several times. The other columns carry information regarding the the unique value. I would also prefer if the original formatting of the file remains.

唯一值以随机顺序重复，但我希望所有这些都是分组在一个文件，以相同的顺序（如果可能）
我找到了另一个代码，但它不工作，因为我的值重复自己。

The unique value repeats itself in a random order, but I want all of them to be grouped in 1 file, in the same order (if possible) I had found another code, but it is not working because my values repeat themselves.

Sub Copy_To_Workbooks()
'Note: This macro use the function LastRow
    Dim My_Range As Range
    Dim FieldNum As Long
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim CalcMode As Long
    Dim ViewMode As Long
    Dim ws2 As Worksheet
    Dim MyPath As String
    Dim foldername As String
    Dim Lrow As Long
    Dim cell As Range
    Dim CCount As Long
    Dim WSNew As Worksheet
    Dim ErrNum As Long
'Set filter range on ActiveSheet: A1 is the top left cell of your filter range
'and the header of the first column, D is the last column in the filter range.
'You can also add the sheet name to the code like this :
'Worksheets("Sheet1").Range("A1:D" & LastRow(Worksheets("Sheet1")))
'No need that the sheet is active then when you run the macro when you use this.
Set My_Range = Range("A1:D" & LastRow(ActiveSheet))
My_Range.Parent.Select

If ActiveWorkbook.ProtectStructure = True Or _
   My_Range.Parent.ProtectContents = True Then
    MsgBox "Sorry, not working when the workbook or worksheet is protected", _
           vbOKOnly, "Copy to new workbook"
    Exit Sub
End If

'This example filters on the first column in the range(change the field if needed)
'In this case the range starts in A so Field:=1 is column A, 2 = column B, ......
FieldNum = 1

'Turn off AutoFilter
My_Range.Parent.AutoFilterMode = False

'Set the file extension/format
If Val(Application.Version) < 12 Then
    'You use Excel 97-2003
    FileExtStr = ".xls": FileFormatNum = -4143
Else
    'You use Excel 2007-2013
    If ActiveWorkbook.FileFormat = 56 Then
        FileExtStr = ".xls": FileFormatNum = 56
    Else
        FileExtStr = ".xlsx": FileFormatNum = 51
    End If
End If

'Change ScreenUpdating, Calculation, EnableEvents, ....
With Application
    CalcMode = .Calculation
    .Calculation = xlCalculationManual
    .ScreenUpdating = False
    .EnableEvents = False
End With
ViewMode = ActiveWindow.View
ActiveWindow.View = xlNormalView
ActiveSheet.DisplayPageBreaks = False

'Delete the sheet RDBLogSheet if it exists
On Error Resume Next
Application.DisplayAlerts = False
Sheets("RDBLogSheet").Delete
Application.DisplayAlerts = True
On Error GoTo 0

' Add worksheet to copy/Paste the unique list
Set ws2 = Worksheets.Add(After:=Sheets(Sheets.Count))
ws2.Name = "RDBLogSheet"

'Fill in the path\folder where you want the new folder with the files
'you can use also this "C:\Users\Ron\test"
MyPath = Application.DefaultFilePath

'Add a slash at the end if the user forget it
If Right(MyPath, 1) <> "\" Then
    MyPath = MyPath & "\"
End If

'Create folder for the new files
foldername = MyPath & Format(Now, "yyyy-mm-dd hh-mm-ss") & "\"
MkDir foldername

With ws2
    'first we copy the Unique data from the filter field to ws2
    My_Range.Columns(FieldNum).AdvancedFilter _
            Action:=xlFilterCopy, _
            CopyToRange:=.Range("A3"), Unique:=True

    'loop through the unique list in ws2 and filter/copy to a new sheet
    Lrow = .Cells(Rows.Count, "A").End(xlUp).Row
    For Each cell In .Range("A4:A" & Lrow)

        'Filter the range
        My_Range.AutoFilter Field:=FieldNum, Criteria1:="=" & _
         Replace(Replace(Replace(cell.Value, "~", "~~"), "*", "~*"), "?", "~?")

        'Check if there are no more then 8192 areas(limit of areas)
        CCount = 0
        On Error Resume Next
        CCount = My_Range.Columns(1).SpecialCells(xlCellTypeVisible) _
                 .Areas(1).Cells.Count
        On Error GoTo 0
        If CCount = 0 Then
            MsgBox "There are more than 8192 areas for the value : " & cell.Value _
                 & vbNewLine & "It is not possible to copy the visible data." _
                 & vbNewLine & "Tip: Sort your data before you use this macro.", _
                   vbOKOnly, "Split in worksheets"
        Else
            'Add new workbook with one sheet
            Set WSNew = Workbooks.Add(xlWBATWorksheet).Worksheets(1)

            'Copy/paste the visible data to the new workbook
            My_Range.SpecialCells(xlCellTypeVisible).Copy
            With WSNew.Range("A1")
                ' Paste:=8 will copy the columnwidth in Excel 2000 and higher
                ' Remove this line if you use Excel 97
                .PasteSpecial Paste:=8
                .PasteSpecial xlPasteValues
                .PasteSpecial xlPasteFormats
                Application.CutCopyMode = False
                .Select
            End With

            'Save the file in the new folder and close it
            On Error Resume Next
            WSNew.Parent.SaveAs foldername & _
                                cell.Value & FileExtStr, FileFormatNum
            If Err.Number > 0 Then
                Err.Clear
                ErrNum = ErrNum + 1

                WSNew.Parent.SaveAs foldername & _
                 "Error_" & Format(ErrNum, "0000") & FileExtStr, FileFormatNum

                .Cells(cell.Row, "B").Formula = "=Hyperlink(""" & foldername & _
                  "Error_" & Format(ErrNum, "0000") & FileExtStr & """)"

                .Cells(cell.Row, "A").Interior.Color = vbRed
            Else
                .Cells(cell.Row, "B").Formula = _
                "=Hyperlink(""" & foldername & cell.Value & FileExtStr & """)"
            End If

            WSNew.Parent.Close False
            On Error GoTo 0
        End If

        'Show all the data in the range
        My_Range.AutoFilter Field:=FieldNum

    Next cell
    .Cells(1, "A").Value = "Red cell: can't use the Unique name as file name"
    .Cells(1, "B").Value = "Created Files (Click on the link to open a file)"
    .Cells(3, "A").Value = "Unique Values"
    .Cells(3, "B").Value = "Full Path and File name"
    .Cells(3, "A").Font.Bold = True
    .Cells(3, "B").Font.Bold = True
    .Columns("A:B").AutoFit

End With

'Turn off AutoFilter
My_Range.Parent.AutoFilterMode = False

If ErrNum > 0 Then
    MsgBox "Rename every WorkSheet name that start with ""Error_"" manually" _
         & vbNewLine & "There are characters in the name that are not allowed" _
         & vbNewLine & "in a sheet name or the worksheet already exist."
End If

'Restore ScreenUpdating, Calculation, EnableEvents, ....
My_Range.Parent.Select
ActiveWindow.View = ViewMode
ws2.Select
With Application
    .ScreenUpdating = True
    .EnableEvents = True
    .Calculation = CalcMode
End With

End Sub


Function LastRow(sh As Worksheet)
    On Error Resume Next
    LastRow = sh.Cells.Find(What:="*", _
                            After:=sh.Range("A1"), _
                            Lookat:=xlPart, _
                            LookIn:=xlValues, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Row
    On Error GoTo 0
End Function

推荐答案

Sub t()
On Error Resume Next
Application.DisplayAlerts = False

Dim new_book As Workbook
Dim newsheet As Worksheet

With ThisWorkbook.Sheets("Hierarchy")  'Replace the sheet name with the raw data sheet name

    Set newsheet = ThisWorkbook.Sheets("cal")

        If newsheet Is Nothing Then
                Worksheets.Add.Name = "cal"
            Else
                ThisWorkbook.Sheets("cal").Delete
                Worksheets.Add.Name = "cal"
        End If

            .Columns("a").Copy

                With ThisWorkbook.Sheets("cal")
                    .Range("a1").PasteSpecial (xlPasteAll)
                    .Columns("a").RemoveDuplicates Columns:=1, Header:=xlYes
                End With

                        For Each cell In ThisWorkbook.Sheets("cal").Columns("a").Cells
                            i = i + 1
                                If i <> 1 And cell.Value <> "" Then
                                    .AutoFilterMode = False
                                    .Rows(1).AutoFilter field:=3, Criteria1:=cell.Value
                                    Set new_book = Workbooks.Add
                                    .UsedRange.Copy
                                    new_book.Sheets(1).Range("a1").PasteSpecial (xlPasteAll)
                                    new_book.SaveAs Filename:=ThisWorkbook.Path & "\" & cell.Value & ".xlsx"
                                    new_book.Sheets(1).UsedRange.Columns.AutoFit
                                    new_book.Save
                                    new_book.Close
                                End If
                        Next cell

                            ThisWorkbook.Sheets("cal").Delete
End With

End Sub

这篇关于将数据从excel工作表分解成多个工作簿的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！