哪个更快更有效 - 对于循环，MATCH，FIND等？ [英] Which is faster and more efficient - For loop, MATCH, FIND, etc?

问题描述

我正在做的是在整个范围内逐个搜索一些字符串，如搜索blah1，如果找到，则退出，否则以相同的方式在整个范围内搜索blah2。 blah's在一列中被搜索。

What I am doing is search some strings one by one in the entire range - like search for "blah1", if found then exit, else search "blah2" in the entire range in the same manner. "blah's" are searched in one column.

现在我只是运行一个For循环代码，如下所示，到目前为止，我的测试工作正常，但是想知道MATCH，FIND或其他方法可能会更快...任何意见？

Right now i am just running a For loop code as shown below which so far works ok in my tests...but was wondering if MATCH, FIND or other methods may be faster...any opinion?

Sub test()

Dim LR As Long
LR = Sheet1.Cells(Rows.Count, "A").End(xlUp).Row

If Cells(1, "B") = "" Then
For i = 1 To LR
If Cells(i, "A") = "blah1" Then
Cells(1, "B") = Cells(i, "A").Row
Cells(1, "C") = Cells(i, "A")
Exit For
End If
Next i
End If

If Cells(1, "B") = "" Then
For i = 1 To LR
If Cells(i, "A") = "blah2" Then
Cells(1, "B") = Cells(i, "A").Row
Cells(1, "C") = Cells(i, "A")
Exit For
End If
Next i
End If

End Sub

推荐答案

尝试这个。因为你的代码重复（对于blah1和blah2），我使用了额外的功能：

Try this one. Since your code is repeated (for "blah1" and "blah2") I used additional function:

Sub test()
    If Sheet1.Cells(1, "B") = "" Then
        If findString("blah1") Then Exit Sub
        If findString("blah2") Then Exit Sub
    End If
End Sub

'Function findString returns TRUE if something found and FALSE otherwise
Function findString(searchString As String) As Boolean
    Dim rng As Range, res

    With Sheet1
        Set rng = .Range("A1:A" & .Cells(.Rows.Count, "A").End(xlUp).Row)

        res = Application.Match(searchString, rng, 0)
        'Application.Match returns error if nothing found
        findString = Not IsError(res)
        If findString Then
            .Cells(1, "B").Value = rng.Cells(res, 1).Row
            .Cells(1, "C").Value = searchString
        End If
    End With
End Function

这篇关于哪个更快更有效 - 对于循环，MATCH，FIND等？的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！