使用 Applescript 在 Excel 2011 中查找和替换 [英] Find and replace in Excel 2011 using Applescript

问题描述

我想知道是否有人可以帮助我.我正在尝试查找和替换 Excel 工作簿中的空格.我希望它在工作簿中搜索我所在的当前工作表，找到"的所有实例并将其替换为".

I was wondering if anyone could help me. I'm trying to find and replace blank spaces in an excel workbook. I want it to search the current sheet I'm on in a workbook, find all instances of "" and replace it with " ".

有人碰巧知道怎么做吗?

Does anyone happen to know how to do this?

推荐答案

With Applescript:

With Applescript:

searchAndReplaceTextInCells("hello", "world")

on searchAndReplaceTextInCells(search_str, replace_str)

    tell application "Microsoft Excel"

        set search_range to range "A:Z"
        set all_found_ranges to {} -- store for the ranges, to manipulate after searching
        set found_range to ""
        set counter to 0
        try
            set found_range to find search_range what search_str with match case
        on error
            log ("No matches found")
        end try

        if (found_range is not "") then
            set first_cell_address to (get address of the cells of found_range) -- we use this to break our loop
            repeat while true
                set counter to counter + 1
                copy found_range to end of all_found_ranges

                -- Now look for next result
                set found_range to find next search_range after found_range
                set cell_address to (get address of the cells of found_range)

                if (cell_address = first_cell_address) then 
                    -- have looped around so we are finished!
                    exit repeat
                end if
            end repeat

        end if

        -- walk all the ranges found and do the string replacing
        repeat with r in all_found_ranges
            set value of r to my replace_chars(the value of r, search_str, replace_str)
        end repeat

        log ("found and replaced " & counter & " items")
    end tell
end searchAndReplaceTextInCells

on replace_chars(this_text, search_string, replacement_string)
    set my text item delimiters to the search_string
    set the item_list to every text item of this_text
    set my text item delimiters to the replacement_string
    set this_text to the item_list as string
    set my text item delimiters to ""
    return this_text
end replace_chars

这篇关于使用 Applescript 在 Excel 2011 中查找和替换的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！